Donate to e Foundation | Murena handsets with /e/OS | Own a part of Murena! Learn more

Commit 384b40ca authored by Mark Rutland's avatar Mark Rutland Committed by Marc Zyngier
Browse files

KVM: arm/arm64: Context-switch ptrauth registers 



When pointer authentication is supported, a guest may wish to use it.
This patch adds the necessary KVM infrastructure for this to work, with
a semi-lazy context switch of the pointer auth state.

Pointer authentication feature is only enabled when VHE is built
in the kernel and present in the CPU implementation so only VHE code
paths are modified.

When we schedule a vcpu, we disable guest usage of pointer
authentication instructions and accesses to the keys. While these are
disabled, we avoid context-switching the keys. When we trap the guest
trying to use pointer authentication functionality, we change to eagerly
context-switching the keys, and enable the feature. The next time the
vcpu is scheduled out/in, we start again. However the host key save is
optimized and implemented inside ptrauth instruction/register access
trap.

Pointer authentication consists of address authentication and generic
authentication, and CPUs in a system might have varied support for
either. Where support for either feature is not uniform, it is hidden
from guests via ID register emulation, as a result of the cpufeature
framework in the host.

Unfortunately, address authentication and generic authentication cannot
be trapped separately, as the architecture provides a single EL2 trap
covering both. If we wish to expose one without the other, we cannot
prevent a (badly-written) guest from intermittently using a feature
which is not uniformly supported (when scheduled on a physical CPU which
supports the relevant feature). Hence, this patch expects both type of
authentication to be present in a cpu.

This switch of key is done from guest enter/exit assembly as preparation
for the upcoming in-kernel pointer authentication support. Hence, these
key switching routines are not implemented in C code as they may cause
pointer authentication key signing error in some situations.

Signed-off-by: default avatarMark Rutland <mark.rutland@arm.com>
[Only VHE, key switch in full assembly, vcpu_has_ptrauth checks
, save host key in ptrauth exception trap]
Signed-off-by: default avatarAmit Daniel Kachhap <amit.kachhap@arm.com>
Reviewed-by: default avatarJulien Thierry <julien.thierry@arm.com>
Cc: Christoffer Dall <christoffer.dall@arm.com>
Cc: kvmarm@lists.cs.columbia.edu
[maz: various fixups]
Signed-off-by: default avatarMarc Zyngier <marc.zyngier@arm.com>
parent b890d75c

arch/arm/include/asm/kvm_emulate.h

+2 −0
Original line number Diff line number Diff line
@@ -343,4 +343,6 @@ static inline unsigned long vcpu_data_host_to_guest(struct kvm_vcpu *vcpu, 
	}

}



static inline void vcpu_ptrauth_setup_lazy(struct kvm_vcpu *vcpu) {}



#endif /* __ARM_KVM_EMULATE_H__ */

arch/arm64/Kconfig

+4 −2
Original line number Diff line number Diff line
@@ -1288,6 +1288,7 @@ menu "ARMv8.3 architectural features" 
config ARM64_PTR_AUTH

	bool "Enable support for pointer authentication"

	default y

	depends on !KVM || ARM64_VHE

	help

	  Pointer authentication (part of the ARMv8.3 Extensions) provides

	  instructions for signing and authenticating pointers against secret
@@ -1301,8 +1302,9 @@ config ARM64_PTR_AUTH 
	  context-switched along with the process.



	  The feature is detected at runtime. If the feature is not present in

	  hardware it will not be advertised to userspace nor will it be

	  enabled.

	  hardware it will not be advertised to userspace/KVM guest nor will it

	  be enabled. However, KVM guest also require VHE mode and hence

	  CONFIG_ARM64_VHE=y option to use this feature.



endmenu

arch/arm64/include/asm/kvm_emulate.h

+16 −0
Original line number Diff line number Diff line
@@ -98,6 +98,22 @@ static inline void vcpu_set_wfe_traps(struct kvm_vcpu *vcpu) 
	vcpu->arch.hcr_el2 |= HCR_TWE;

}



static inline void vcpu_ptrauth_enable(struct kvm_vcpu *vcpu)

{

	vcpu->arch.hcr_el2 |= (HCR_API | HCR_APK);

}



static inline void vcpu_ptrauth_disable(struct kvm_vcpu *vcpu)

{

	vcpu->arch.hcr_el2 &= ~(HCR_API | HCR_APK);

}



static inline void vcpu_ptrauth_setup_lazy(struct kvm_vcpu *vcpu)

{

	if (vcpu_has_ptrauth(vcpu))

		vcpu_ptrauth_disable(vcpu);

}



static inline unsigned long vcpu_get_vsesr(struct kvm_vcpu *vcpu)

{

	return vcpu->arch.vsesr_el2;

arch/arm64/include/asm/kvm_host.h

+14 −0
Original line number Diff line number Diff line
@@ -161,6 +161,18 @@ enum vcpu_sysreg { 
	PMSWINC_EL0,	/* Software Increment Register */

	PMUSERENR_EL0,	/* User Enable Register */



	/* Pointer Authentication Registers in a strict increasing order. */

	APIAKEYLO_EL1,

	APIAKEYHI_EL1,

	APIBKEYLO_EL1,

	APIBKEYHI_EL1,

	APDAKEYLO_EL1,

	APDAKEYHI_EL1,

	APDBKEYLO_EL1,

	APDBKEYHI_EL1,

	APGAKEYLO_EL1,

	APGAKEYHI_EL1,



	/* 32bit specific registers. Keep them at the end of the range */

	DACR32_EL2,	/* Domain Access Control Register */

	IFSR32_EL2,	/* Instruction Fault Status Register */
@@ -530,6 +542,8 @@ static inline bool kvm_arch_requires_vhe(void) 
	return false;

}



void kvm_arm_vcpu_ptrauth_trap(struct kvm_vcpu *vcpu);



static inline void kvm_arch_hardware_unsetup(void) {}

static inline void kvm_arch_sync_events(struct kvm *kvm) {}

static inline void kvm_arch_sched_in(struct kvm_vcpu *vcpu, int cpu) {}

arch/arm64/include/asm/kvm_ptrauth.h

0 → 100644
+111 −0
Original line number Diff line number Diff line 
/* SPDX-License-Identifier: GPL-2.0 */

/* arch/arm64/include/asm/kvm_ptrauth.h: Guest/host ptrauth save/restore

 * Copyright 2019 Arm Limited

 * Authors: Mark Rutland <mark.rutland@arm.com>

 *         Amit Daniel Kachhap <amit.kachhap@arm.com>

 */



#ifndef __ASM_KVM_PTRAUTH_H

#define __ASM_KVM_PTRAUTH_H



#ifdef __ASSEMBLY__



#include <asm/sysreg.h>



#ifdef	CONFIG_ARM64_PTR_AUTH



#define PTRAUTH_REG_OFFSET(x)	(x - CPU_APIAKEYLO_EL1)



/*

 * CPU_AP*_EL1 values exceed immediate offset range (512) for stp

 * instruction so below macros takes CPU_APIAKEYLO_EL1 as base and

 * calculates the offset of the keys from this base to avoid an extra add

 * instruction. These macros assumes the keys offsets follow the order of

 * the sysreg enum in kvm_host.h.

 */

.macro	ptrauth_save_state base, reg1, reg2

	mrs_s	\reg1, SYS_APIAKEYLO_EL1

	mrs_s	\reg2, SYS_APIAKEYHI_EL1

	stp	\reg1, \reg2, [\base, #PTRAUTH_REG_OFFSET(CPU_APIAKEYLO_EL1)]

	mrs_s	\reg1, SYS_APIBKEYLO_EL1

	mrs_s	\reg2, SYS_APIBKEYHI_EL1

	stp	\reg1, \reg2, [\base, #PTRAUTH_REG_OFFSET(CPU_APIBKEYLO_EL1)]

	mrs_s	\reg1, SYS_APDAKEYLO_EL1

	mrs_s	\reg2, SYS_APDAKEYHI_EL1

	stp	\reg1, \reg2, [\base, #PTRAUTH_REG_OFFSET(CPU_APDAKEYLO_EL1)]

	mrs_s	\reg1, SYS_APDBKEYLO_EL1

	mrs_s	\reg2, SYS_APDBKEYHI_EL1

	stp	\reg1, \reg2, [\base, #PTRAUTH_REG_OFFSET(CPU_APDBKEYLO_EL1)]

	mrs_s	\reg1, SYS_APGAKEYLO_EL1

	mrs_s	\reg2, SYS_APGAKEYHI_EL1

	stp	\reg1, \reg2, [\base, #PTRAUTH_REG_OFFSET(CPU_APGAKEYLO_EL1)]

.endm



.macro	ptrauth_restore_state base, reg1, reg2

	ldp	\reg1, \reg2, [\base, #PTRAUTH_REG_OFFSET(CPU_APIAKEYLO_EL1)]

	msr_s	SYS_APIAKEYLO_EL1, \reg1

	msr_s	SYS_APIAKEYHI_EL1, \reg2

	ldp	\reg1, \reg2, [\base, #PTRAUTH_REG_OFFSET(CPU_APIBKEYLO_EL1)]

	msr_s	SYS_APIBKEYLO_EL1, \reg1

	msr_s	SYS_APIBKEYHI_EL1, \reg2

	ldp	\reg1, \reg2, [\base, #PTRAUTH_REG_OFFSET(CPU_APDAKEYLO_EL1)]

	msr_s	SYS_APDAKEYLO_EL1, \reg1

	msr_s	SYS_APDAKEYHI_EL1, \reg2

	ldp	\reg1, \reg2, [\base, #PTRAUTH_REG_OFFSET(CPU_APDBKEYLO_EL1)]

	msr_s	SYS_APDBKEYLO_EL1, \reg1

	msr_s	SYS_APDBKEYHI_EL1, \reg2

	ldp	\reg1, \reg2, [\base, #PTRAUTH_REG_OFFSET(CPU_APGAKEYLO_EL1)]

	msr_s	SYS_APGAKEYLO_EL1, \reg1

	msr_s	SYS_APGAKEYHI_EL1, \reg2

.endm



/*

 * Both ptrauth_switch_to_guest and ptrauth_switch_to_host macros will

 * check for the presence of one of the cpufeature flag

 * ARM64_HAS_ADDRESS_AUTH_ARCH or ARM64_HAS_ADDRESS_AUTH_IMP_DEF and

 * then proceed ahead with the save/restore of Pointer Authentication

 * key registers.

 */

.macro ptrauth_switch_to_guest g_ctxt, reg1, reg2, reg3

alternative_if ARM64_HAS_ADDRESS_AUTH_ARCH

	b	1000f

alternative_else_nop_endif

alternative_if_not ARM64_HAS_ADDRESS_AUTH_IMP_DEF

	b	1001f

alternative_else_nop_endif

1000:

	ldr	\reg1, [\g_ctxt, #(VCPU_HCR_EL2 - VCPU_CONTEXT)]

	and	\reg1, \reg1, #(HCR_API | HCR_APK)

	cbz	\reg1, 1001f

	add	\reg1, \g_ctxt, #CPU_APIAKEYLO_EL1

	ptrauth_restore_state	\reg1, \reg2, \reg3

1001:

.endm



.macro ptrauth_switch_to_host g_ctxt, h_ctxt, reg1, reg2, reg3

alternative_if ARM64_HAS_ADDRESS_AUTH_ARCH

	b	2000f

alternative_else_nop_endif

alternative_if_not ARM64_HAS_ADDRESS_AUTH_IMP_DEF

	b	2001f

alternative_else_nop_endif

2000:

	ldr	\reg1, [\g_ctxt, #(VCPU_HCR_EL2 - VCPU_CONTEXT)]

	and	\reg1, \reg1, #(HCR_API | HCR_APK)

	cbz	\reg1, 2001f

	add	\reg1, \g_ctxt, #CPU_APIAKEYLO_EL1

	ptrauth_save_state	\reg1, \reg2, \reg3

	add	\reg1, \h_ctxt, #CPU_APIAKEYLO_EL1

	ptrauth_restore_state	\reg1, \reg2, \reg3

	isb

2001:

.endm



#else /* !CONFIG_ARM64_PTR_AUTH */

.macro ptrauth_switch_to_guest g_ctxt, reg1, reg2, reg3

.endm

.macro ptrauth_switch_to_host g_ctxt, h_ctxt, reg1, reg2, reg3

.endm

#endif /* CONFIG_ARM64_PTR_AUTH */

#endif /* __ASSEMBLY__ */

#endif /* __ASM_KVM_PTRAUTH_H */